Introduction to Qyoto

In this part of the Visual Basic Qyoto programming tutorial, we will introduce the Qyoto library and create our first Qyoto programs using the Visual Basic programming language.

The purpose of this tutorial is to get you started with the Qyoto and Visual Basic. Images used in this tutorial can be downloaded here. I used some icons from the tango icons pack of the Gnome project.

About

Qyoto is a library that provides binding of the Qt library to the .NET languages like C# or Visual Basic. Qt is a powerful cross-platform application development framework. Its native language is C++. Qyoto is a part of the KDE desktop environment.

vbnc -r:/usr/lib/cli/qyoto-4.3/qt-dotnet.dll quitbutton.vb

The above command shows, how to compile the quitbutton example. The -r parameter of the mono VB compiler loads the Qt assembly. It is a dynamic library. The command shows a path to the dll library on a Ubuntu system.

Creating a Tooltip

The first example will show a tooltip. A tooltip is a small rectangular window, which gives a brief information about an object. It is usually a GUI component. It is part of the help system of the application.

' ZetCode Mono Visual Basic Qt tutorial
'
' This program displays
' a tooltip
'
' author jan bodnar
' last modified May 2009
' website www.zetcode.com

Imports Qyoto


Public Class VBQApp 
    Inherits QWidget

    Public Sub New()
    
        Me.InitUI()
        
    End Sub
    
    Private Sub InitUI()
    
        Me.Tooltip = "This is QWidget"
        
        Me.SetWindowTitle("Tooltip")
        Me.Resize(250, 150)
        Me.Move(300, 300)
        Me.Show()
        
    End Sub

    Public Shared Sub Main(ByVal args() As String)
        Dim qapp As New QApplication(args)
        Dim app As New VBQApp
        QApplication.Exec()
    End Sub

End Class

The example creates a window. If we hover a mouse pointer over the area of the window, a tooltip pops up.

Imports Qyoto

The Imports keyword imports necessary types that we will use in the application.

Public Class VBQApp 
    Inherits QWidget

The example inherits from a QWidget. The QWidget class is the base class of all user interface objects. The widget is the atom of the user interface. It receives mouse, keyboard and other events from the window system.

Me.SetWindowTitle("Tooltip")

This method call creates a title for the window.

Me.Tooltip = "This is QWidget"

We set a tooltip through the ToolTip property.

Me.Resize(250, 150)

Here we set the width and the height of the window.

Me.Move(300, 300)

The Move() method moves the window on the screen.

Me.Show()

When everything is ready, we show the window on the screen.

Dim qapp As New QApplication(args)
Dim app As New VBQApp
QApplication.Exec()

These three lines set up the application.

Tooltip
Figure: Tooltip

Centering a window

In the second example, we will center the window on the screen.

' ZetCode Mono Visual Basic Qt tutorial
'
' This program centers a window
' on the screen
'
' author jan bodnar
' last modified May 2009
' website www.zetcode.com


Imports Qyoto


Public Class VBQApp 
    Inherits QWidget

    Dim WIDTH As Integer = 250
    Dim HEIGHT As Integer = 150

    Public Sub New()
    
        Me.InitUI()
        
    End Sub
    
    Private Sub InitUI()
    
        Dim qdw As New QDesktopWidget

        Dim screenWidth As Integer = qdw.Width()
        Dim screenHeight As Integer = qdw.Height()

        Dim x As Integer = (screenWidth - WIDTH) / 2
        Dim y As Integer = (screenHeight - HEIGHT) / 2
        
        Me.SetWindowTitle("Center")
        Me.Resize(WIDTH, HEIGHT)
        Me.Move(x, y)
        Me.Show()
        
    End Sub

    Public Shared Sub Main(ByVal args() As String)
        Dim qapp As New QApplication(args)
        Dim app As New VBQApp
        QApplication.Exec()
    End Sub

End Class

The Qyoto does not have a single method to center a window.

Dim WIDTH As Integer = 250
Dim HEIGHT As Integer = 150

These two constants define the width and height of the application window.

Dim qdw As New QDesktopWidget

The QDesktopWidget class provides information about the screen.

Dim screenWidth As Integer = qdw.Width()
Dim screenHeight As Integer = qdw.Height()

Here we determine the screen width and height.

Dim x As Integer = (screenWidth - WIDTH) / 2
Dim y As Integer = (screenHeight - HEIGHT) / 2

Here we calculate the x, y coordinates of the centered window. To center a window on the screen, we need to know the size of the screen and the size of the window.

Me.Move(x, y)

We move the window to the computed x, y coordinates.

Quit button

In the last example of this section, we will create a quit button. When we press this button, the application terminates.

' ZetCode Mono Visual Basic Qt tutorial
'
' This program creates a quit
' button. When we press the button,
' the application terminates. 
'
' author jan bodnar
' last modified May 2009
' website www.zetcode.com


Imports Qyoto


Public Class VBQApp 
    Inherits QWidget

    Public Sub New()
     
        Me.SetWindowTitle("Quit button")
    
        Me.InitUI()
        
        Me.Resize(250, 150)
        Me.Move(300, 300)
        Me.Show()
        
    End Sub
    
    Private Sub InitUI()
    
        Dim quit As New QPushButton("Quit", Me)
        
        Connect(quit, SIGNAL("clicked()"), qApp, SLOT("quit()"))
        quit.Move(30, 30)
        
    End Sub

    Public Shared Sub Main(ByVal args() As String)
        Dim qapp As New QApplication(args)
        Dim app As New VBQApp
        QApplication.Exec()
    End Sub

End Class

We use the QPushButton. This is a very common widget. It is rectangular and usually shows a text label.

Me.InitUI()

We delegate the creation of the user interface to the InitUI() method.

Dim quit As New QPushButton("Quit", Me)

We create the button widget. The first parameter of the constructor is the label, which the button displays. The second parameter is the parent widget of the button.

Connect(quit, SIGNAL("clicked()"), qApp, SLOT("quit()"))

The clicked() signal is emitted, when we click on the button. The Connect() method connects a signal to a particular slot of an object. The first parameter of the method is the object that receives the signal. In our case it is the application object. The second parameter is the method, which is called. In our case it is the quit() method of the application object. The qApp is a global reference to the application object.

Quit button
Figure: Quit button

This section was an introduction to the Qyoto library with the Visual Basic language.